技术标签: batch-file arguments
我需要在运行时将ID和密码传递给批处理文件,而不是将其硬编码为文件。
命令行如下所示:
test.cmd admin P@55w0rd > test-log.txt
无需使其复杂化。 例如,它只是命令%1%2的参数,
@echo off
xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z
echo copied %1 to %2
pause
“暂停”显示批处理文件已完成的操作,并等待您按ANY键。 将其另存为Windows文件夹中的xx.bat。
要使用它,请键入,例如:
xx c:\f\30\*.* f:\sites\30
该批处理文件处理所有必要的参数,例如仅复制文件,更新文件等。自Windows之前我就使用它。 如果要查看正在复制的文件名,请省略Q
参数。
要在命令行中引用set变量,您将需要使用%a%
这样,例如:
set a=100
echo %a%
rem output = 100
注意:这适用于Windows 7专业版。
@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue
注意:如果将%1
括在引号本身中,则如果"%1"==""
会引起问题。
在这种情况下,请使用IF [%1]==[]
或者仅在NT 4(SP6)和更高版本中使用IF "%~1"==""
。
是的,只是在使用if
和for
和gang时不要忘记使用%%1
类的变量。
如果您忘记了双精度%
,那么您将用(可能为null)命令行参数替换,并且会收到一些非常令人困惑的错误消息。
另一个有用的技巧是使用%*
表示“全部”。 例如:
echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*
运行时:
test-command admin password foo bar
上面的批处理文件将运行:
fake-command /u admin /p password admin password foo bar
我的语法可能有些错误,但这是一般的想法。
如果要智能处理丢失的参数,可以执行以下操作:
IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1
:No1
ECHO No param 1
GOTO End1
:No2
ECHO No param 2
GOTO End1
:End1
FOR %%A IN (%*) DO (
REM Now your batch file handles %%A instead of %1
REM No need to use SHIFT anymore.
ECHO %%A
)
这会循环引用或不引用批处理参数(%*),然后回显每个参数。
让我们保持简单。
这是.cmd文件。
@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%
这是从命令行进行的3个调用。
C:\Users\joeco>echo_3params 1abc 2 def 3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def
C:\Users\joeco>echo_3params 1abc "2 def" "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"
C:\Users\joeco>echo_3params 1abc '2 def' "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'
C:\Users\joeco>
我编写了一个简单的read_params脚本,可以将其称为函数(或外部.bat
),并将所有变量放入当前环境中。 它不会修改原始参数,因为正在使用原始参数的副本call
该函数。
例如,给出以下命令:
myscript.bat some -random=43 extra -greeting="hello world" fluff
myscript.bat
将能够在调用函数后使用变量:
call :read_params %*
echo %random%
echo %greeting%
功能如下:
:read_params
if not %1/==/ (
if not "%__var%"=="" (
if not "%__var:~0,1%"=="-" (
endlocal
goto read_params
)
endlocal & set %__var:~1%=%~1
) else (
setlocal & set __var=%~1
)
shift
goto read_params
)
exit /B
局限性
-force
。 您可以使用-force=true
但是我想不了一种方法来允许空白值,而无需提前知道没有值的参数列表。 变更日志
-
与其他命令行参数一起使用。 最近有一个朋友问我有关此主题的信息,所以我认为我应该发布如何处理批处理文件中的命令行参数。
如您所见,该技术会产生一些开销,但是它使我的批处理文件非常容易理解和快速实现。 以及支持以下结构:
>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]
它的关键是具有:init
, :parse
和:main
函数。
用法示例
>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
USAGE:
test.bat [flags] "required argument" "optional argument"
/?, --help shows this help
/v, --version shows the version
/e, --verbose shows detailed output
-f, --flag value specifies a named parameter value
>template.bat <- throws missing argument error
(same as /?, plus..)
**** ****
**** MISSING "REQUIRED ARGUMENT" ****
**** ****
>template.bat -v
1.23
>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.
>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument: "arg1"
UnNamedOptionalArg: not provided
NamedFlag: not provided
>template.bat --flag "my flag" arg1 arg2
UnNamedArgument: "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag: "my flag"
>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument: "argument #1"
UnNamedOptionalArg: "second"
NamedFlag: "my flag"
template.bat
@::!/dos/rocks
@echo off
goto :init
:header
echo %__NAME% v%__VERSION%
echo This is a sample batch file template,
echo providing command-line arguments and flags.
echo.
goto :eof
:usage
echo USAGE:
echo %__BAT_NAME% [flags] "required argument" "optional argument"
echo.
echo. /?, --help shows this help
echo. /v, --version shows the version
echo. /e, --verbose shows detailed output
echo. -f, --flag value specifies a named parameter value
goto :eof
:version
if "%~1"=="full" call :header & goto :eof
echo %__VERSION%
goto :eof
:missing_argument
call :header
call :usage
echo.
echo **** ****
echo **** MISSING "REQUIRED ARGUMENT" ****
echo **** ****
echo.
goto :eof
:init
set "__NAME=%~n0"
set "__VERSION=1.23"
set "__YEAR=2017"
set "__BAT_FILE=%~0"
set "__BAT_PATH=%~dp0"
set "__BAT_NAME=%~nx0"
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedOptionalArg="
set "NamedFlag="
:parse
if "%~1"=="" goto :validate
if /i "%~1"=="/?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="-?" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="--help" call :header & call :usage "%~2" & goto :end
if /i "%~1"=="/v" call :version & goto :end
if /i "%~1"=="-v" call :version & goto :end
if /i "%~1"=="--version" call :version full & goto :end
if /i "%~1"=="/e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="-e" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--verbose" set "OptVerbose=yes" & shift & goto :parse
if /i "%~1"=="--flag" set "NamedFlag=%~2" & shift & shift & goto :parse
if not defined UnNamedArgument set "UnNamedArgument=%~1" & shift & goto :parse
if not defined UnNamedOptionalArg set "UnNamedOptionalArg=%~1" & shift & goto :parse
shift
goto :parse
:validate
if not defined UnNamedArgument call :missing_argument & goto :end
:main
if defined OptVerbose (
echo **** DEBUG IS ON
)
echo UnNamedArgument: "%UnNamedArgument%"
if defined UnNamedOptionalArg echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
if not defined UnNamedOptionalArg echo UnNamedOptionalArg: not provided
if defined NamedFlag echo NamedFlag: "%NamedFlag%"
if not defined NamedFlag echo NamedFlag: not provided
:end
call :cleanup
exit /B
:cleanup
REM The cleanup function is only really necessary if you
REM are _not_ using SETLOCAL.
set "__NAME="
set "__VERSION="
set "__YEAR="
set "__BAT_FILE="
set "__BAT_PATH="
set "__BAT_NAME="
set "OptHelp="
set "OptVersion="
set "OptVerbose="
set "UnNamedArgument="
set "UnNamedArgument2="
set "NamedFlag="
goto :eof
制作一个新的批处理文件(例如:openclass.bat),并将此行写入文件中:
java %~n1
然后将批处理文件放在(例如)system32文件夹中,转到您的Java类文件,右键单击“属性”,“打开方式为...”,然后找到您的批处理文件,将其选中,就是这样...
这个对我有用。
PS:关闭Java类时,找不到关闭cmd窗口的方法。 目前...
受@Jon 在其他地方给出的答案的启发,我设计了一种更通用的算法来提取命名参数,可选值和开关。
假设我们要实现实用程序foobar
。 它需要一个初始命令。 它有一个可选参数--foo
,它带有一个可选值(当然不能是另一个参数); 如果缺少该值,则默认为default
。 它还具有一个可选参数--bar
,该参数采用必需的值。 最后,它可以带一个标志--baz
,不允许值。 哦,这些参数可以按任何顺序排列。
换句话说,它看起来像这样:
foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]
这是一个解决方案:
@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson
SET CMD=%~1
IF "%CMD%" == "" (
GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=
SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
SHIFT
IF NOT "%ARG%" == "" (
IF NOT "%ARG:~0,2%" == "--" (
SET FOO=%ARG%
SHIFT
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE (
SET FOO=%DEFAULT_FOO%
)
) ELSE IF "%PARAM%" == "--bar" (
SHIFT
IF NOT "%ARG%" == "" (
SET BAR=%ARG%
SHIFT
) ELSE (
ECHO Missing bar value. 1>&2
ECHO:
GOTO usage
)
) ELSE IF "%PARAM%" == "--baz" (
SHIFT
SET BAZ=true
) ELSE IF "%PARAM%" == "" (
GOTO endargs
) ELSE (
ECHO Unrecognized option %1. 1>&2
ECHO:
GOTO usage
)
GOTO args
:endargs
ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
ECHO Baz
)
REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof
:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1
SETLOCAL
以便变量不会逸出到调用环境中。 SET FOO=
。 %~1
删除引号。 IF "%ARG%" == ""
而不要使用IF [%ARG%] == []
因为[
和]
根本不会播放以空格结尾的值。 SHIFT
内部IF
块,当前ARGS比如%~1
没有得到,因为当他们决定更新IF
解析。 您可以在IF
块中使用%~1
和%~2
IF
,但这会造成混淆,因为您有SHIFT
。 为了清楚起见,您可以将SHIFT
放在块的末尾,但这可能会迷失和/或使人们感到困惑。 因此,最好在块外“捕获” %~1
和%~1
。 IF NOT "%ARG:~0,2%" == "--"
。 SHIFT
。 SET FOO=%DEFAULT_FOO%
,但替代方法是在IF NOT "%ARG%" == ""
块外添加IF "%FOO%" == "" SET FOO=%DEFAULT_FOO%
。 但是,由于这仍是里面的IF "%PARAM%" == "--foo"
块中, %FOO%
的值将被评估,并设置之前,你从来没有入过块,所以你永远不会发现, 无论是--foo
参数存在,并且还使得%FOO%
值丢失。 ECHO Missing bar value. 1>&2
ECHO Missing bar value. 1>&2
将错误消息发送到stderr。 ECHO:
或其中一种变体。 简单的解决方案(即使问题很旧)
Test1.bat
echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause
CallTest1.bat
call "C:\Temp\Test1.bat" pass123
输出
YourLocalPath>call "C:\Temp\test.bat" pass123
YourLocalPath>echo off
"Batch started"
"arg1 is pass123"
YourLocalPath>pause
Press any key to continue . . .
其中YourLocalPath是当前目录路径。
为了简单起见,将命令参数存储在变量中,并使用变量进行比较。
它不仅易于编写,而且易于维护,因此,如果以后有人或长时间阅读脚本后,将易于理解和维护。
内联编写代码:请参阅其他答案。
要使用循环,请使用纯批处理获取所有参数:
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
)
goto :eof
您的代码已准备就绪,可以在需要的地方使用参数编号进行处理,例如...
@echo off && setlocal EnableDelayedExpansion
set "_cnt=0" && for %%Z in (%*) do (
set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
shift
)
fake-command /u !_arg_[1]! /p !_arg_[2]! > test-log.txt
使用%1,%2,...%9或%*,可以轻松访问批处理参数。
但前提是内容简单。
对于诸如"&"^&
类的复杂内容,没有简单的方法,因为无法访问%1而不会产生错误。
set var=%1
set "var=%1"
set var=%~1
set "var=%~1"
线扩大到
set var="&"&
set "var="&"&"
set var="&"&
set "var="&"&"
每行都会失败,因为&
之一在引号之外。
可以通过从临时文件中读取该参数的标记版本来解决。
@echo off
SETLOCAL DisableDelayedExpansion
SETLOCAL
for %%a in (1) do (
set "prompt="
echo on
for %%b in (1) do rem * #%1#
@echo off
) > param.txt
ENDLOCAL
for /F "delims=" %%L in (param.txt) do (
set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'
诀窍是在rem
语句之后启用echo on
并扩展%1(也可用于%2 .. %*
)。
因此,即使"&"&
也可以在不产生错误的情况下回显,如前所述。
但是要能够重定向echo on
的输出,您需要两个for循环。
多余的字符* #
用于防止诸如/?
内容/?
(将显示REM
的帮助)。
或者,即使在rem
之后,行尾的插入符号^也可以用作多行字符。
然后仔细阅读文件中的rem参数输出。
FOR / F应该在延迟扩展关闭的情况下工作,否则内容应带有“!” 将被摧毁。
在删除param1
的多余字符之后,您就知道了。
为了安全使用param1
,请启用延迟扩展。
在批处理文件中
set argument1=%1
set argument2=%2
echo %argument1%
echo %argument2%
%1和%2分别返回第一个和第二个参数值。
然后在命令行中通过thestrmt
Directory> batchFileName admin P@55w0rd
输出将是
admin
P@55w0rd
这是我的操作方式:
@fake-command /u %1 /p %2
该命令如下所示:
test.cmd admin P@55w0rd > test-log.txt
%1
适用于第一个参数, %2
(这是棘手的部分)适用于第二个参数。 通过这种方式,您最多可以传递9个参数。
文章浏览阅读3.7w次。发票批量查验软件(自动保存官网查验截图)91发票查验助手_91发票查验助手
文章浏览阅读7.8k次,点赞4次,收藏6次。WPF控件是Windows Presentation Foundation(WPF)中的基本用户界面元素。它们是可视化对象,可以用来创建各种用户界面。WPF控件可以分为两类:原生控件和自定义控件。原生控件是由Microsoft提供的内置控件,如Button、TextBox、Label、ComboBox等。这些控件都是WPF中常见的标准用户界面元素。自定义控件则允许开发人员使用XAML和C#等编程语言来创建个性化的用户界面元素。自定义控件可以根据需求提供更多的功能和自定义化选项,以及更好的用户体验。_wpf popup
文章浏览阅读72次。这是因为VM开发框架与你的目标框架不同导致,点击属性将目标框架切换到对应即可,如果不行就都试一遍,我这里是4.7.1,VM4.3,谢谢支持与点赞。
文章浏览阅读776次。在使用Elastic Job Lite做定时任务的时候,我发现很多开发的团队都是直接部署单点,这对于一些离线的非核心业务(如对账、监控等)或许无关紧要,但对于一些高可用补偿、核心数据定时修改(如金融场景的利息更新等),单点部署则“非常危险”。实际上,Elastic Job Lite是支持高可用的。网上关于Elastic Job的较高级的博文甚少,本文试图结合自身实践的一些经验,大致讲解其方案原理,并延伸至同城双机房的架构实践。单点部署到高可用如本文开头所说,很多系统的部署是采取以下部署架构:_es集群 双活方案
文章浏览阅读2.5k次。更多内容关注公众号:SAP Technical各位可以关注我的公众号:SAP Technical查询物料的上阶方法有三:1. CS15 可直接查出物料的上阶直至顶阶物料.2. CALL FUNCTION. 只能查上上阶, 要想得到顶阶, 需要递归查询.CS_WHERE_USED_MAT Bills of material; where-used li..._abap bom反查至最上层
文章浏览阅读7k次,点赞7次,收藏37次。JavaScript是由Netscape(网景)公司研发出来的一种在它的Navigator浏览器上执行的程序语言。JavaScript是一种基于对象(object-based)和事件驱动(Event Driven)的简单的并具有安全性能的脚本语言。JavaScript组成ECMAScript:JavaScript的核心,语法格式,使用方法文档对象模型(DOM,document object model):DOM(文档对象模型)是 HTML 和 XML 的应用程序接口(API)。_js
文章浏览阅读203次。java计算机毕业设计随心淘网管理系统源代码+数据库+系统+lw文档。springboot基于B_S架构的疫情包联信息管理系统的设计与实现。springboot基于精细化考核的离散数学课程教学目标达成系统。springboot基于Springboot的大学宿舍管理系统。ssm临港新片区招商引资项目管理系统的设计与实现。_jsp__access_在线网络购物系统_ssm疫情背景下基于web的学生信息日报系统。JSP广告公司网站的设计与实现mysql。jsp基于javaweb的公益募捐网站。
文章浏览阅读233次。首先,在“开始”菜单栏中找到Oracle-OraDB19Home1(因安装版本不同可能会有差异),接着打开Net Configuration Assistant,进行监听程序的配置;使用dos命令(windows徽标+R--输入cmd)/菜单栏搜索框直接输入cmd,输入lsnrctl status;监听程序配置完成后再通过cmd输入lsnrctl status命令,测试如下则说明监听程序已配置完成;Oracle主目录用户口令即在下载Oracle时自定义的口令密码;若如下图显示则是尚未开启监听程序;
文章浏览阅读152次。数组、链表、堆、栈、队列、树、哈希、图。_java数据结构
文章浏览阅读1.1k次。C++11常用特性总结1、关键字及新语法C++11相比C++98增加了许多关键字及新的语法特性,很多人觉得这些语法可有可无,没有新特性也可以用传统C++去实现。也许吧,但个人对待新技术总是抱着渴望而热衷的态度对待,也许正如很多人所想,用传统语法也可以实现,但新技术可以让你的设计更完美。这就如同在原来的维度里,你要完成一件事情,需要很多个复杂的步骤,但在新语法特性里,你可以从另外的维度,很干脆,直接就把原来很复杂的问题用很简单的方法解决了,我想着就是新的技术带来的一些编程体验上非常好的感觉。大家也不要觉_c11新特性
文章浏览阅读3.2k次。1.从mysql导入到hive的ods层的shell脚本传参表示要导入的数据分期日期,sqoop导入,实例:#!/bin/bashexport SQOOP_HOME=/usr/bin/sqoopif [ $# == 1 ] then dateStr=$1 else dateStr=`date -d '-1 day' +'%Y-%m-%d'`fidateNowStr=`date +'%Y-%m-%d'`yearStr=`date -d ${dateStr}_shell一个脚本同时导入导出数据
文章浏览阅读1.1k次。-王大海 2009-03-12 06:25(二) 使用Delphi 控件方法在Form中分别放入ExcelApplication, ExcelWorkbook和ExcelWorksheet。1) 打开Excel :ExcelApplication1.Connect;2) 显示当前窗口:ExcelApplication1.Visible[0]:=True;3) 更改 ..._python win32 被呼叫方拒绝接收呼叫