技术标签: UnityShader # Unity3D
一个一个来(绿色的部分暂时可以不用了解):
其中对于点光源还有一个A半径属性,对于聚光灯还有一个B张角属性
关于阴影部分:
关于物体是否接受阴影的设置:
其中将 Cast Shadows 设置为 Two Sided 后,对应物体的所有面都会计算阴影信息
可以参考 OpenGL 的部分教程:
一个好消息是,关于阴影的计算 Unity 已经帮我们写好了,如不是需要特殊定制,不需要写太多的代码
在新版本的 Unity 里,其采用了屏幕空间阴影映射技术(Screenspace Shadow Map)来计算阴影,这也是原先延迟渲染中产生阴影的方法,不过对于部分显卡不支持 MRT 的平台可能就不支持这种特性
只需要在之前的基础上更改3个地方就可以了:
1):内置宏 SHADOW_COORDS() 或 LIGHTING_COORDS(,):
struct vert2frag
{
float4 pos: SV_POSITION;
float3 wPos: TEXCOORD0;
float3 wNormal: TEXCOORD1;
float2 uv: TEXCOORD2;
SHADOW_COORDS(3)
};
内置宏的参数需要一个可用的插值寄存器索引值,它的作用就是声明一个用于阴影纹理采样坐标 _ShadowCoord
而对于 LIGHTING_COORDS 宏,它同时声明了用于阴影纹理采样坐标 _ShadowCoord 和用于衰减纹理采样坐标 _LightCoord
2):内置宏 TRANSFER_SHADOW 或 TRANSFER_VERTEX_TO_FRAGMENT:
vert2frag vert(_2vert v)
{
vert2frag o;
//……
TRANSFER_SHADOW(o);
return o;
}
该宏的展开为一段计算阴影纹理坐标的代码,它会使用 v.vertex 或 v.pos 来计算坐标 _ShadowCoord,因此你需要保证这两个变量名要与宏内的代码相匹配,除此之外,顶点着色器的输入参数变量名也必须为 v
而对于 TRANSFER_VERTEX_TO_FRAGMENT 宏,它同时计算了 _ShadowCoord 和用于衰减纹理采样坐标 _LightCoord 坐标
如果当前平台可以使用屏幕空间阴影映射技术(通过判断是否定义了 UNITY_NO_SCREENSPACE_SHADOWS 来得到),那么 TRANSFER_SHADOW 就会调用内置的 ComputeScreenPos 来计算 _ShadowCoord
3):内置宏 SHADOW_ATTENUATION() 或 LIGHT_ATTENUATION(i):
fixed4 frag(vert2frag i): SV_Target
{
//……
fixed shadow = SHADOW_ATTENUATION(i);
return fixed4((diffuse + specular) * atten * shadow, 1.0);
}
ENDCG
该宏的展开为计算阴影值,就和衰减值一样,其范围为 [0, 1],使用 LIGHT_ATTENUATION 宏可以同时计算阴影值和衰减值,它当然要和 LIGHTING_COORDS(,) 宏与 TRANSFER_VERTEX_TO_FRAGMENT 宏对应
最后得到的效果如下:
其它的点:
上面的内容都是为了实现让物体接收阴影,而让物体投射阴影不需要我们进行任何处理,只需要设置 Fallback 语义为 Specular 就可以了:
FallBack "Specular"
这是因为对于内置的 Specular,它的 Fallback 又调用了 VertexLit,对于这个内置的 Shader:VertexLit,它的里面实现了 LightMode 为 ShadowCaster 的 Pass,这个 Pass 的主要目的是把深度信息写入渲染目标中,这个渲染目标可以是阴影映射纹理,或是摄像机的深度纹理
如果开启了透明度测试,需要设置 Fallback 为 Transparent/Cutout/VertexLit(这个 ShadowCaster Pass 也同时计算了透明度测试),并且必须提供 _Cutoff 属性、设置物体的 CastShadow 属性为 Two Sided
4):内置宏 UNITY_LIGHT_ATTENUATION(atten, i, worldPos):
其中第一个参数为衰减值(充当输出),第二个参数为片段着色器输入 v2f,第三个参数为顶点时间空间坐标,这个宏直接帮我们同时计算了光照衰减和阴影,有了它之后就不需要根据光源的类型来写判断自己算衰减了
当然了,这个宏现在已经基本不用了,既然要 Unity 帮我们同时计算阴影值和衰减值,上面的 LIGHT_ATTENUATION(i) 宏会是一个更好的选择
Unity 针对不同的光源类型、是否启用 cookie 等多种情况声明了多个版本的 UNITY_LIGHT_ATTENUATION
// Upgrade NOTE: replaced '_LightMatrix0' with 'unity_WorldToLight'
Shader "Jaihk662/AllInOne1"
{
Properties
{
_DiffuseColor ("DiffuseColor", Color) = (1.0, 1.0, 1.0, 1.0)
_SpecularColor ("SpecularColor", Color) = (1.0, 1.0, 1.0, 1.0)
_MainTex ("MainTex", 2D) = "white" {}
_NormalMap ("NormalMap", 2D) = "bump" {}
_NormalScale ("NormalScale", float) = 1.0 //控制法线贴图展现的凹凸效果,0~1
_SpecularMask ("SpecularMask", 2D) = "white" {}
_SpecularMaskScale ("SpecularMaskScale", float) = 1.0
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader
{
LOD 200
Tags { "RenderType" = "Opaque" "Queue" = "Geometry" }
//如果场景中包含了多个平行光,Unity会选择最亮的那个传递给BasePass进行逐像素处理,其它平行光按照逐顶点或在AddPass中按逐像素处理(没有平行光默认全黑)
PASS
{
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma multi_compile_fwdbase
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _DiffuseColor;
fixed4 _SpecularColor;
sampler2D _MainTex;
sampler2D _NormalMap;
float _Gloss;
float _NormalScale;
sampler2D _SpecularMask;
float _SpecularMaskScale;
float4 _MainTex_ST;
struct _2vert
{
float4 vertex: POSITION; //这个名字vertex不可修改,不然Unity内置宏就无法识别到
float3 normal: NORMAL;
float4 tangent: TANGENT;
float4 texcoord: TEXCOORD0;
};
struct vert2frag
{
float4 pos: SV_POSITION; //这个名字pos不可修改
float2 uv: TEXCOORD0;
float4 TtoW1 : TEXCOORD1; //世界空间中的顶点坐标wPos放在了这3个float4的第四维里
float4 TtoW2 : TEXCOORD2;
float4 TtoW3 : TEXCOORD3;
SHADOW_COORDS(4)
};
vert2frag vert(_2vert v) //这个输入参数v不可修改
{
vert2frag o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
TANGENT_SPACE_ROTATION;
float3 wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 wNormal = UnityObjectToWorldNormal(v.normal);
fixed3 wTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 wBinormal = cross(wNormal, wTangent) * v.tangent.w;
o.TtoW1 = float4(wTangent.x, wBinormal.x, wNormal.x, wPos.x);
o.TtoW2 = float4(wTangent.y, wBinormal.y, wNormal.y, wPos.y);
o.TtoW3 = float4(wTangent.z, wBinormal.z, wNormal.z, wPos.z);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(vert2frag i): SV_Target
{
float3 wPos = float3(i.TtoW1.w, i.TtoW2.w, i.TtoW3.w);
fixed3 normal = UnpackNormal(tex2D(_NormalMap, i.uv)); //内置函数UnpackNormal自动帮我们将法线向量由[0,1]映射到[-1,1]
normal.xy *= _NormalScale;
normal.z = sqrt(1.0 - saturate(dot(normal.xy, normal.xy))); //反正是标准化过的单位向量,可以自己由xy算出z的值
normal = normalize(half3(dot(i.TtoW1.xyz, normal), dot(i.TtoW2.xyz, normal), dot(i.TtoW3.xyz, normal)));
fixed3 wLightDir = normalize(UnityWorldSpaceLightDir(wPos));
fixed3 wViewDir = normalize(UnityWorldSpaceViewDir(wPos));
fixed3 albedo = tex2D(_MainTex, i.uv) * _DiffuseColor.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(normal, wLightDir));
fixed3 reflectDir = normalize(reflect(-wLightDir, normal));
fixed specularMask = tex2D(_SpecularMask, i.uv).g * _SpecularMaskScale;
fixed3 specular = specularMask * _LightColor0.rgb * _SpecularColor.rgb * pow(saturate(dot(reflectDir, wViewDir)), _Gloss);
UNITY_LIGHT_ATTENUATION(atten, i, wPos);
return fixed4(ambient + (diffuse + specular) * atten, 1.0);
}
ENDCG
}
PASS
{
Tags { "LightMode" = "ForwardAdd" }
Blend One One
CGPROGRAM
#pragma vertex vert
#pragma multi_compile_fwdadd_fullshadows //使用此编译指令就能确保在 AddPass 中生成阴影
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _DiffuseColor;
fixed4 _SpecularColor;
sampler2D _MainTex;
sampler2D _NormalMap;
float _Gloss;
float _NormalScale;
sampler2D _SpecularMask;
float _SpecularMaskScale;
float4 _MainTex_ST;
struct _2vert
{
float4 vertex: POSITION; //这个名字vertex不可修改,不然Unity内置宏就无法识别到
float3 normal: NORMAL;
float4 tangent: TANGENT;
float4 texcoord: TEXCOORD0;
};
struct vert2frag
{
float4 pos: SV_POSITION; //这个名字pos不可修改
float2 uv: TEXCOORD0;
float4 TtoW1 : TEXCOORD1; //世界空间中的顶点坐标wPos放在了这3个float4的第四维里
float4 TtoW2 : TEXCOORD2;
float4 TtoW3 : TEXCOORD3;
SHADOW_COORDS(4)
};
vert2frag vert(_2vert v) //这个输入参数v不可修改
{
vert2frag o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
TANGENT_SPACE_ROTATION;
float3 wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 wNormal = UnityObjectToWorldNormal(v.normal);
fixed3 wTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 wBinormal = cross(wNormal, wTangent) * v.tangent.w;
o.TtoW1 = float4(wTangent.x, wBinormal.x, wNormal.x, wPos.x);
o.TtoW2 = float4(wTangent.y, wBinormal.y, wNormal.y, wPos.y);
o.TtoW3 = float4(wTangent.z, wBinormal.z, wNormal.z, wPos.z);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(vert2frag i): SV_Target
{
float3 wPos = float3(i.TtoW1.w, i.TtoW2.w, i.TtoW3.w);
fixed3 normal = UnpackNormal(tex2D(_NormalMap, i.uv)); //内置函数UnpackNormal自动帮我们将法线向量由[0,1]映射到[-1,1]
normal.xy *= _NormalScale;
normal.z = sqrt(1.0 - saturate(dot(normal.xy, normal.xy))); //反正是标准化过的单位向量,可以自己由xy算出z的值
normal = normalize(half3(dot(i.TtoW1.xyz, normal), dot(i.TtoW2.xyz, normal), dot(i.TtoW3.xyz, normal)));
fixed3 wLightDir = normalize(UnityWorldSpaceLightDir(wPos));
fixed3 wViewDir = normalize(UnityWorldSpaceViewDir(wPos));
fixed3 albedo = tex2D(_MainTex, i.uv) * _DiffuseColor.rgb;
fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(normal, wLightDir));
fixed3 reflectDir = normalize(reflect(-wLightDir, normal));
fixed specularMask = tex2D(_SpecularMask, i.uv).g * _SpecularMaskScale;
fixed3 specular = specularMask * _LightColor0.rgb * _SpecularColor.rgb * pow(saturate(dot(reflectDir, wViewDir)), _Gloss);
UNITY_LIGHT_ATTENUATION(atten, i, wPos);
return fixed4((diffuse + specular) * atten, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}
上面的代码同时也考虑了法线贴图
打开 FrameDebug 也可以看到阴影的渲染过程,总计的渲染步骤多出了不少,但是可以大致分为4个步骤:
对于透明度混合:如果想要半透明物体也得到正确的阴影,其实是一件非常困难的事,不但对于每个光源都要给出合理的渲染顺序,而且就算按照一般的方法渲染得到了正确的阴影,也不会是完全正确的,因为半透明物体的阴影并不只是简单的“衰减”,还需要额外考虑其材质的散射光学特性
想要实现一个非常不错的半透明阴影效果,可能需要去参考专攻的论文,并且就算能实现,其性能消耗也难以接受,所以一般对于半透明物体,直接不去计算阴影
文章浏览阅读1.6k次。安装配置gi、安装数据库软件、dbca建库见下:http://blog.csdn.net/kadwf123/article/details/784299611、检查集群节点及状态:[root@rac2 ~]# olsnodes -srac1 Activerac2 Activerac3 Activerac4 Active[root@rac2 ~]_12c查看crs状态
文章浏览阅读1.3w次,点赞45次,收藏99次。我个人用的是anaconda3的一个python集成环境,自带jupyter notebook,但在我打开jupyter notebook界面后,却找不到对应的虚拟环境,原来是jupyter notebook只是通用于下载anaconda时自带的环境,其他环境要想使用必须手动下载一些库:1.首先进入到自己创建的虚拟环境(pytorch是虚拟环境的名字)activate pytorch2.在该环境下下载这个库conda install ipykernelconda install nb__jupyter没有pytorch环境
文章浏览阅读5.2k次,点赞19次,收藏28次。选择scoop纯属意外,也是无奈,因为电脑用户被锁了管理员权限,所有exe安装程序都无法安装,只可以用绿色软件,最后被我发现scoop,省去了到处下载XXX绿色版的烦恼,当然scoop里需要管理员权限的软件也跟我无缘了(譬如everything)。推荐添加dorado这个bucket镜像,里面很多中文软件,但是部分国外的软件下载地址在github,可能无法下载。以上两个是官方bucket的国内镜像,所有软件建议优先从这里下载。上面可以看到很多bucket以及软件数。如果官网登陆不了可以试一下以下方式。_scoop-cn
文章浏览阅读4.5k次,点赞2次,收藏3次。首先要有一个color-picker组件 <el-color-picker v-model="headcolor"></el-color-picker>在data里面data() { return {headcolor: ’ #278add ’ //这里可以选择一个默认的颜色} }然后在你想要改变颜色的地方用v-bind绑定就好了,例如:这里的:sty..._vue el-color-picker
文章浏览阅读640次。基于芯片日益增长的问题,所以内核开发者们引入了新的方法,就是在内核中只保留函数,而数据则不包含,由用户(应用程序员)自己把数据按照规定的格式编写,并放在约定的地方,为了不占用过多的内存,还要求数据以根精简的方式编写。boot启动时,传参给内核,告诉内核设备树文件和kernel的位置,内核启动时根据地址去找到设备树文件,再利用专用的编译器去反编译dtb文件,将dtb还原成数据结构,以供驱动的函数去调用。firmware是三星的一个固件的设备信息,因为找不到固件,所以内核启动不成功。_exynos 4412 刷机
文章浏览阅读2w次,点赞24次,收藏42次。Linux系统配置jdkLinux学习教程,Linux入门教程(超详细)_linux配置jdk
文章浏览阅读3.3k次,点赞5次,收藏19次。xlabel('\delta');ylabel('AUC');具体符号的对照表参照下图:_matlab微米怎么输入
文章浏览阅读119次。顺序读写指的是按照文件中数据的顺序进行读取或写入。对于文本文件,可以使用fgets、fputs、fscanf、fprintf等函数进行顺序读写。在C语言中,对文件的操作通常涉及文件的打开、读写以及关闭。文件的打开使用fopen函数,而关闭则使用fclose函数。在C语言中,可以使用fread和fwrite函数进行二进制读写。 Biaoge 于2024-03-09 23:51发布 阅读量:7 ️文章类型:【 C语言程序设计 】在C语言中,用于打开文件的函数是____,用于关闭文件的函数是____。
文章浏览阅读3.4k次,点赞2次,收藏13次。跟随鼠标移动的粒子以grid(SOP)为partical(SOP)的资源模板,调整后连接【Geo组合+point spirit(MAT)】,在连接【feedback组合】适当调整。影响粒子动态的节点【metaball(SOP)+force(SOP)】添加mouse in(CHOP)鼠标位置到metaball的坐标,实现鼠标影响。..._touchdesigner怎么让一个模型跟着鼠标移动
文章浏览阅读178次。项目运行环境配置:Jdk1.8 + Tomcat7.0 + Mysql + HBuilderX(Webstorm也行)+ Eclispe(IntelliJ IDEA,Eclispe,MyEclispe,Sts都支持)。项目技术:Springboot + mybatis + Maven +mysql5.7或8.0+html+css+js等等组成,B/S模式 + Maven管理等等。环境需要1.运行环境:最好是java jdk 1.8,我们在这个平台上运行的。其他版本理论上也可以。_基于java技术的停车场管理系统实现与设计
文章浏览阅读3.5k次。前言对于MediaPlayer播放器的源码分析内容相对来说比较多,会从Java-&amp;gt;Jni-&amp;gt;C/C++慢慢分析,后面会慢慢更新。另外,博客只作为自己学习记录的一种方式,对于其他的不过多的评论。MediaPlayerDemopublic class MainActivity extends AppCompatActivity implements SurfaceHolder.Cal..._android多媒体播放源码分析 时序图
文章浏览阅读2.4k次,点赞41次,收藏13次。java 数据结构与算法 ——快速排序法_快速排序法