1.ALV 相关参数定义

代码如下：

DATA: gcl_alvgrid TYPE REF TO cl_gui_alv_grid,
      gcl_docking TYPE REF TO cl_gui_docking_container,
*      gc_container TYPE REF TO cl_gui_custom_container,"控件
*      gc_container TYPE REF TO cl_gui_docking_container, "全屏
      gc_textedit TYPE REF TO cl_gui_textedit,
      gt_fieldcat TYPE lvc_t_fcat,
      gs_fieldcat TYPE lvc_s_fcat,
      gs_layout   TYPE lvc_s_layo,
      gt_toolbar  TYPE ui_functions.

2.定义OOALV的单击事件及实现

CLASS cl_event_receiver DEFINITION.
  PUBLIC SECTION.
    " 声明单击事件的方法
    CLASS-METHODS handle_hotspot_click FOR EVENT hotspot_click OF cl_gui_alv_grid    "屏幕中的单击事件，可以具体到某行某列，需要设置热点
      IMPORTING e_row_id e_column_id es_row_no.
ENDCLASS.

CLASS cl_event_receiver IMPLEMENTATION.  "实现类方法
  "ALV内表展示处单击事件捕捉，需要设置热点对单击列字段
  METHOD handle_hotspot_click.
    CLEAR gs_alv.
    READ TABLE gt_alv INTO gs_alv INDEX es_row_no-row_id. "判断行号
    "点设备号(EQUNR)调用tcode IE03，点资产号(ANLNR)调用AS03
    CASE e_column_id-fieldname . "判断列名
      WHEN 'EQUNR'.
        SET PARAMETER ID 'EQN' FIELD gs_alv-equnr.
        CALL TRANSACTION 'IE03' WITH AUTHORITY-CHECK AND SKIP FIRST SCREEN. "点设备号(EQUNR)调用IE03,参数：设备号
      WHEN 'ANLN1'.
        SET PARAMETER ID: 'AN1' FIELD gs_alv-anln1,
                          'BUK' FIELD gs_alv-bukrs.
        CALL TRANSACTION 'AS03' WITH AUTHORITY-CHECK AND SKIP FIRST SCREEN."调入方，点资产号(ANLN1)调用AS03，参数：资产号+公司号
    ENDCASE.
    CLEAR gs_alv.
  ENDMETHOD.

3.获取数据并展示

代码如下：

START-OF-SELECTION.
*----------------------逻辑取数------------------*
  PERFORM frm_query_data.

*-----------------------展示数据---------------------*
  PERFORM frm_show_data.
  
  FORM frm_show_data .
  "创建ALV结构
  	PERFORM frm_build_fcat.

  "设置ALV输出格式及保存变式
  	PERFORM frm_set_layout.

  "显示ALV数据
	PERFORM frm_display_alv.

  	CALL SCREEN 100.
ENDFORM.

4.表头字段设置

代码如下：

FORM frm_build_fcat .
	DEFINE fieldcat_add.
		CLEAR gs_fieldcat.
		l_index  = l_index + 1.
 		gs_fieldcat-col_pos    = l_index.
 	    gs_fieldcat-fieldname  = &1.
 		gs_fieldcat-reptext    = &2.
 		gs_fieldcat-outputlen  = &3.
 		gs_fieldcat-no_zero    = &4.
 		gs_fieldcat-decimals   = &5.
 		gs_fieldcat-just       = &6.
 		gs_fieldcat-hotspot    = &7.
 		gs_fieldcat-ref_table  = &8.
 		gs_fieldcat-edit       = &9.			"这一列设为可编辑状态
 		APPEND gs_fieldcat TO gt_fieldcat.
 	END-OF-DEFINITION.
 	l_index = 1.
 	fieldcat_add 'XUHAO'         '序号' '' '' '' '' '' '' ''.
 	fieldcat_add 'BUKRS'         '公司代码' '' '' '' '' '' '' ''.
 	fieldcat_add 'ANLN1'         '财务资产编码' '' '' '' '' 'X' '' ''.
 	fieldcat_add 'ANLKL'         '财务资产类别' '' '' '' '' '' '' ''.
 	fieldcat_add 'TXT50'         '财务资产名称' '' '' '' '' '' '' ''.
 	fieldcat_add 'MENGE'         '财务数量' '' '' '' '' '' '' ''.
 	fieldcat_add 'MEINS'         '财务单位' '' '' '' '' '' '' ''.
 	fieldcat_add 'KOSTLV'        '财务成本中心' '' '' '' '' '' '' ''.
 	fieldcat_add 'EQUNR'         'PM资产号' '' '' '' '' 'X' '' ''.
ENDFORM.

5.ALV输出格式

代码如下

FORM frm_set_layout .
  CLEAR: gs_layout.
  gs_layout-grid_title = 'OO-ALV报表'.
  gs_layout-zebra = 'X'.
  gs_layout-cwidth_opt = 'X'.
  gs_layout-no_merging = 'X'.
  gs_layout-sel_mode = 'C'."'A'.
  gs_layout-edit_mode = 'X'.
  "gs_layout-box_fname = 'SEL'.
ENDFORM.

6.展示ALV

代码如下

FORM frm_display_alv .
  DATA: lt_tools TYPE TABLE OF sy-ucomm.   "用于排除按钮
  DATA: cl_event_receiver TYPE REF TO cl_event_receiver.
  DATA ls_stbl TYPE lvc_s_stbl.

  FIELD-SYMBOLS: <lfs_tab> TYPE STANDARD TABLE.
  ls_stbl-row = 'X'." 基于行的稳定刷新
  ls_stbl-col = 'X'." 基于列稳定刷新

  ASSIGN gt_alv TO <lfs_tab>.

  CHECK <lfs_tab> IS ASSIGNED.

  IF gcl_docking IS NOT BOUND.
    CREATE OBJECT gcl_docking
      EXPORTING
*       parent                      =
        repid                       = sy-repid
        dynnr                       = '0100'
        side                        = cl_gui_docking_container=>dock_at_bottom "dock_at_top
        extension                   = 500
*       style                       =
*       lifetime                    = lifetime_default
*       caption                     =
*       metric                      = 0
*       ratio                       = 0
*       no_autodef_progid_dynnr     =
*       name                        =
      EXCEPTIONS
        cntl_error                  = 1
        cntl_system_error           = 2
        create_error                = 3
        lifetime_error              = 4
        lifetime_dynpro_dynpro_link = 5
        OTHERS                      = 6.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
                 WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.


    CREATE OBJECT gcl_alvgrid
      EXPORTING
*       i_shellstyle      = 0
*       i_lifetime        =
        i_parent          = gcl_docking
*       i_appl_events     = space
*       i_parentdbg       =
*       i_applogparent    =
*       i_graphicsparent  =
*       i_name            =
*       i_fcat_complete   = SPACE
      EXCEPTIONS
        error_cntl_create = 1
        error_cntl_init   = 2
        error_cntl_link   = 3
        error_dp_create   = 4
        OTHERS            = 5.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
                 WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.

    CALL METHOD gcl_alvgrid->set_table_for_first_display
      EXPORTING
*       i_buffer_active               =
*       i_bypassing_buffer            =
*       i_consistency_check           =
*       i_structure_name              =
*       is_variant                    =
        i_save                        = 'A'
*       i_default                     = 'X'
        is_layout                     = gs_layout
*       is_print                      =
*       it_special_groups             =
        it_toolbar_excluding          = lt_tools
*       it_hyperlink                  =
*       it_alv_graphics               =
*       it_except_qinfo               =
*       ir_salv_adapter               =
      CHANGING
        it_outtab                     = <lfs_tab>
        it_fieldcatalog               = gt_fieldcat
*       it_sort                       =
*       it_filter                     =
      EXCEPTIONS
        invalid_parameter_combination = 1
        program_error                 = 2
        too_many_lines                = 3
        OTHERS                        = 4.
  ELSE.
    " PERFORM frm_refresh_alv USING gcl_alvgrid.

    CALL METHOD cl_gui_cfw=>flush
      EXCEPTIONS
        cntl_system_error = 1
        cntl_error        = 2
        OTHERS            = 3.

******注册ALV中引用的事件
  ENDIF.
  CREATE OBJECT cl_event_receiver.
  SET HANDLER cl_event_receiver=>handle_hotspot_click
              "alv_event_receiver=>handle_double_click
           FOR ALL INSTANCES.
ENDFORM.

7.其他

在100屏幕设置status和title

PROCESS BEFORE OUTPUT.
 MODULE STATUS_0100.
*
PROCESS AFTER INPUT.
 MODULE USER_COMMAND_0100.

MODULE status_0100 OUTPUT.
 SET PF-STATUS 'STA_100'.
 SET TITLEBAR 'TILLE100'.
ENDMODULE.

MODULE user_command_0100 INPUT.
  CASE ok_code.
  	WHEN 'BACK' OR 'CANCLE'.
    	LEAVE TO SCREEN 0.
    WHEN 'EXIT'.
   		 LEAVE PROGRAM.
   	WHEN OTHERS.
  ENDCASE.
ENDMODULE.