技术标签: 命令行
https://www.jb51.net/article/18973_all.htm
set,E文翻译过来就是“设置”的意思,相当于数学里的“令”。
如:set X=5,就是令X=5的意思。
语法形式:
SET [variable=[string]]
SET /P variable=[promptString]
SET /A expression
一、SET [variable=[string]]
示例1:
@echo off
set
pause
显示所有的变量的值
示例2:
@echo off
set var=我是值
echo %var%
pause
请看 set var=我是值 ,这就是BAT直接在批处理中设置变量的方法!
set 是命令 var是变量名 =号右边的"我是值"是变量的值
在批处理中我们要引用这个变量就把var变量名用两个%(百分号)扩起来,如%var%
二、SET /P variable=[promptString]
有时候我们需要提供一个交互界面,让 用户自己输入变量的值,然后我们在来根据这个值来做相应操作,现在我就来说说这SET的这 种语法,只需要加一个"/P"参数就可以了!
实例1:
@echo off
set /p var=请输入你的名字:
echo 您的名字是:%var%
pause
set /p 是命令语法 var是变量名 =号右边的"请输入变量的值: ",这个是提示语,不是变
量的值了!
运行后,我们在提示语后面直接输入robin,就会显示一行您” 您的名字是:robin”
三、SET /A expression
/A 命令行开关指定等号右边的字符串为被评估的数字表达式。
该表达式解析很简单并以递减的优先权顺序支持下列操作:
() - 分组
! ~ - - 一元运算符
* / % - 算数运算符
+ - - 算数运算符
<< >> - 逻辑移位
& - 按位“与”
^ - 按位“异”
| - 按位“或”
= *= /= %= += -= &= ^= |= <<= >>= - 赋值
, - 表达式分隔符
set的/A参数就是让SET可以支持数学符号进行加减等一些数学运算!
现在开始举例子介绍这些数学符号的用法:
看例子 这里的例子请直接在CMD下拷贝命令运行,不需要保存为BAT!
set /a var=1 + 1
set /a 语法, var变量名 1 + 1 数学式子
拷贝运行后会直接显示一个2,或者运行完后我们输入echo %var%,也是二,这就是
一个简单的加法运算!
复制代码代码如下:
set /a var=2 - 1 结果是多少呢?如果你看不到结果就echo %var%.....
set /a var=2 * 2 乘法运算
set /a var=2 / 2 除法运算
set /a var=(1+1) + (1+1) 结果等于4 看得懂吧!
实例1:
复制代码代码如下:
@echo off
set /a a=1+1,b=2+1,c=3+1
echo %a% %b% %c%
实例2:
复制代码代码如下:
@echo off
set a=100
set b=1000
set /a c=a+b
echo the result is :%c%
pause
有时候我们需要直接在原变量进行加减操作就可以用这种语法
set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1
都是一样的结果,在原变量的值上在进行数学运算,不过这样写简单一点
在来一个:
set /a var*=2
其他都这么用,只要帮助里有这个语法!
另外还有一些用逻辑或取余操作符,这些符号,按照上面的使用方法会报错的
比如我们在CMD里输入set /a var=1 & 1 "与运算",他并不会显示为1,而是报错,
为什么?对于这样的"逻辑或取余操作符",我们需要把他们用双引号引起来,看例子
复制代码代码如下:
set /a var= 1 "&" 1 这样结果就显示出来了,其他逻辑或取余操作符用法
set /a var= 1 "^" 1 异运算
set /a var= 1 "%" 1 取模运算
set /a var= 2 "<<" 2 位左移
set /a var= 4 ">>" 2 位右移
实例3:
复制代码代码如下:
@echo off
set a=100
set b=1000
set /a c=a+b
set /a c= c "<<" 2
echo the result is :%c%
pause
这些符号也可以用&= ^= |= <<= >>= 这样的简单用法如
set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号
set的通常用法示例:
1、set 显示环境变量:
如:在命令行下输入:
set 会显示当前所有的系统环境变量
set c 会显示所有的以c开头或C开头的变量(也即不区分大小写);
set com 会显示所有的以com开头或COM开头的变量(不区分大小写);
2、set 设置环境变量,用法示例:set 表达式,
如:set str=ok
就是将变量str的值设置成字符串“OK”
注意:set str=ok>
这个在批处理运行过程中会出错,系统会提示:“命令语法不正确。”
原因是,因为 变量str 中的值“ok>”的字符">"为一特殊字符,会被系统当成 定向 符处理,所以会运行出错,那如果确实要设置这样的变量str,值为 "ok>"怎么办呢?解决办法有二:将特殊字符转义,转义方法在该特殊字符前加一个“^”,如:set str=ok^> (这种方法比较少用,因为没有多少应用价值)
常见的解决办法,在set后面将整个表达式用 引号括起来,如:set "str=>"
3、带参数 /a的set 数值计算
set的/A参数就是让SET可以支持数学符号进行加减等一些数学运算! 支持的数学运算包含(优先权递减):
() - 分组
! ~ - - 一元运算符
* / % - 算数运算符
+ - - 算数运算符
<< >> - 逻辑移位
& - 按位“与”
^ - 按位“异”
| - 按位“或”
= *= /= %= += -= - 赋值
&= ^= |= <<= >>=
, - 表达式分隔符
用法示例:set /a num=2*10,这样变量num的值将变为:20
复制代码代码如下:
set /a var=2 - 1 结果是多少呢?如果你看不到结果就echo %var%.....
set /a var=2 * 2 乘法运算
set /a var=2 / 2 除法运算
set /a var=(1+1) + (1+1) 结果等于4 看得懂吧!
set /a a=1+1,b=2+1,c=3+1 运行后会显示一个4,但我们用
echo %a% %b% %c%后看结果,会发现其他数学运算也有效果!,这就是"斗"号的
作用!
有时候我们需要直接在原变量进行加减操作就可以用这种语法
set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1
都是一样的结果。
对于"逻辑或取余操作符",我们需要把他们用双引号引起来,看例子
复制代码代码如下:
set /a var= 1 "&" 1 这样结果就显示出来了,其他逻辑或取余操作符用法
set /a var= 1 "+" 1 异运算
set /a var= 1 "%" 1 取模运算
set /a var= 2 "<<" 2 次方运算
set /a var= 4 ">>" 2 这个不太记得数学里的叫法....
这些符号也可以用&= ^= |= <<= >>= 这样的简单用法如
set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号
4、带参数 /p 的set 等待用户输入
windows 2000 和windows 是没有choice这个命令,choice的等待用户输入功能就要通过set /p来实现
演示如下:
复制代码代码如下:
@echo off
set /p str=请输入你想输入的字符:
echo 你输入的字符串为:%str%
pause>nul
set /p的特殊应用(set /p=<nul相当于输出字符并不带回车,利用这个性质,可以做出比较漂亮的动画),用法示例:
复制代码代码如下:
@echo off
for /l %%i in (1 1 70) do (
set /p=O<nul
for /l %%a in (1 1 50) do ver>nul
)
pause>nul
注:代码中用到了一句for /l %%a in (1 1 50) do ver>nul,它的目的是利用for循环运行某一命令来达到延时的目的。
5、利用set截取字符 保存下面的代码为test.bat运行查看即可。
复制代码代码如下:
@echo off&color 1f&rem num=15 nums=30
mode con: cols=80 lines=35
set "var=1234567890"
set "num= "
set "nums= "
rem 第一屏 舍弃
cls&echo 第一屏 舍弃
echo\&echo %num% var=%var%&echo\
for /l %%i in (1 1 3) do call :dan %%i
echo\
for /l %%i in (0 1 1) do call :yi %%i
echo\
for /l %%i in (0 1 2) do call :_yi %%i
echo ~ 波浪号后面的数字:为正数表示舍弃变量的前位;
echo , 逗号后面的数字为正数表示取变量的舍弃以后的前几位;
echo , 逗号后面为负数表示舍弃变量的后几位
echo\&echo\&pause&color 1e
rem 第二屏 取
cls&echo 第二屏 取
echo\&echo %num% var=%var%&echo\
for /l %%i in (-1 -1 -3) do call :dan %%i
echo\
for /l %%i in (-4 -1 -6) do call :er %%i
echo\
call :_er -8
echo ~ 波浪号后面直接跟负数表示取变量的后几位
echo , 逗号后面的数字为正数表示取变量的舍弃以后的前几位;
echo , 逗号后面为负数表示舍弃变量的后几位
echo\&echo\&pause&color 1f
rem 第三屏 替换 删除
cls&echo 第三屏 替换 删除
set "var=abc:\123\ef:g\123\456"hij"789"klm\"
echo\&echo %num%var=%var%
echo\
call :san
echo = 号左边为要替换掉的字符, 右边为需替换来的字符
echo = 号左边要替换掉的字符前面加个*号,代表第一次出现的字符及其前面的所有字符
echo\
echo ========= 演示完毕 ========= 按任意键退出 ==========
pause>nul
exit
:dan
set shu=%1
if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍弃&set ji=前
if "%shu:~0,1%"=="-" set shu=%shu:~1%
set str1=%%var:~%1%%%num%
set str2=%aa%var的%ji%%shu%位%nums%
call set str3=%%var:~%1%%%num%
call echo %%str1:~0,15%% %%str2:~0,30%% %%str3:~0,15%%
goto :eof
:yi
set shu=%1
if %shu% lss 0 (set aa=取&set ji=最后) else set aa=舍弃&set ji=前
for /l %%i in (1 1 3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=%aa%var的%ji%%shu%位之后取%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,26%% %%str3:~0,15%%
if %%i==3 echo\
)
goto :eof
:_yi
for /l %%i in (-1 -1 -3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=舍弃var的前%1位和%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,28%% %%str3:~0,15%%
if %%i==-3 echo\
)
goto :eof
:er
set sss=%1
set sss=%sss:~1%
for /l %%i in (1 1 3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=从var的倒数%sss%位开始取%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,24%% %%str3:~0,15%%
if %%i==3 echo\
)
goto :eof
:_er
set sss=%1
set sss=%sss:~1%
for /l %%i in (-1 -1 -3) do (
set str1=%%var:~%1,%%i%%%num%
set str2=从var的倒数%sss%位开始并舍弃最后%%i位%nums%
call set str3=%%var:~%1,%%i%%%num%
call echo %%str1:~0,15%% %%str2:~0,20%% %%str3:~0,15%%
if %%i==-3 echo\
)
goto :eof
:san
set str1=%%var:"=%%%num%
set str2=删除var中的所有^"号%num%
set str3=%var:"=%%nums%
call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%
set str1=%%var:\=%%%num%
set str2=删除var中的所有\号%num%
set str3=%var:\=%%nums%
call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%
set str1=%%var::=%%%num%
set str2=删除var中的所有:号%num%
set str3=%var::=%%nums%
call echo %%str1:~0,13%% %%str2:~0,23%% %%str3:~0,30%%
echo\
set str1=%%var:"=好%%%num%
set str2=替换var中的所有^"号为好字%num%
set str3=%var:"=好%%nums%
call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%
set str1=%%var:\=好%%%num%
set str2=替换var中的所有\号为好字%num%
set str3=%var:\=好%%nums%
call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%
set str1=%%var::=好%%%num%
set str2=替换var中的所有:号为好字%num%
set str3=%var::=好%%nums%
call echo %%str1:~0,12%% %%str2:~0,20%% %%str3:~0,30%%
echo\
set str1=%%var:*"=%%%num%
set str3=%var:*"=%%nums%
echo 删除var中的第一次出现的^"号及其前面的所有字符
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*\=%%%num%
set str3=%var:*\=%%nums%
echo 删除var中的第一次出现的\号及其前面的所有字符
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*:=%%%num%
set str3=%var:*:=%%nums%
echo 删除var中的第一次出现的:号及其前面的所有字符
call echo %%str1:~0,15%% %%str3:~0,30%%
echo\
set str1=%%var:*"=ppp%%%num%
set str3=%var:*"=ppp%%nums%
echo 替换var中的第一次出现的^"号及其前面的所有字符为ppp
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*\=ppp%%%num%
set str3=%var:*\=ppp%%nums%
echo 替换var中的第一次出现的\号及其前面的所有字符为ppp
call echo %%str1:~0,15%% %%str3:~0,30%%
echo.
set str1=%%var:*:=ppp%%%num%
set str3=%var:*:=ppp%%nums%
echo 替换var中的第一次出现的:号及其前面的所有字符为ppp
call echo %%str1:~0,15%% %%str3:~0,30%%
echo\
goto :eof
批处理Set命令详解 补充篇
一、设置自定义变量
复制代码代码如下:
@echo off
set var=我是值
echo %var%
pause
二、设置自定义变量,并接受用户输入作为值
复制代码代码如下:
@echo off
@echo off
set /p var=请输入变量的值:
if %var% == 1 echo 您输入了 1 ~_~
pause
三、SET /A expression
set的/A参数就是让SET可以支持数学符号进行加减等一些数学运算! 支持的数学运算包含(优先权递减):
复制代码代码如下:
() - 分组
! ~ - - 一元运算符
* / % - 算数运算符
+ - - 算数运算符
<< >> - 逻辑移位
& - 按位“与”
^ - 按位“异”
| - 按位“或”
= *= /= %= += -= - 赋值
&= ^= |= <<= >>=
, - 表达式分隔符
Batch代码
复制代码代码如下:
set /a var=2 - 1 结果是多少呢?如果你看不到结果就echo %var%.....
set /a var=2 * 2 乘法运算
set /a var=2 / 2 除法运算
set /a var=(1+1) + (1+1) 结果等于4 看得懂吧!
set /a a=1+1,b=2+1,c=3+1 运行后会显示一个4,但我们用
echo %a% %b% %c%后看结果,会发现其他数学运算也有效果!,这就是"斗"号的作用!
有时候我们需要直接在原变量进行加减操作就可以用这种语法
set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1
都是一样的结果。
对于"逻辑或取余操作符",我们需要把他们用双引号引起来,看例子
Batch代码
复制代码代码如下:
set /a var= 1 "&" 1 这样结果就显示出来了,其他逻辑或取余操作符用法
set /a var= 1 "+" 1 异运算
set /a var= 1 "%" 1 取模运算
set /a var= 2 "<<" 2 次方运算
set /a var= 4 ">>" 2 这个不太记得数学里的叫法....
这些符号也可以用&= ^= |= <<= >>= 这样的简单用法如
set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号
下面是一个具体的例子:
复制代码代码如下:
@echo off
set p=123
title 密码是%p%
set n=1
:in
if %n% gtr 3 goto wrong
set /p a=请输入您需要登陆的密码:
if "%a%" equ "%p%" goto right
set/a n+=1
goto in
:right
echo 猜对了,新年快乐!
goto end
:wrong
echo 已经输过3次了,还不正确,退出!
:end
pause
四、替换变量值的内容
语法:set newVar="oldVar:str1=str2%
将变量oldVar的值中的str1替换成str2,并将替换后的变量值赋给newVar.
看例子
复制代码代码如下:
@echo off
set a=bbs.verybat.cn
echo 替换前的值: "%a%"
set var=%a:bbs=sss%
echo 替换后的值: "%var%"
pause
对比一下,我们发现他把变量%a%的bbs给替换掉了,换成了sss.
五、字符串截取
1、%Var:~start,len%
注意:从0开始。
例如:
复制代码代码如下:
@echo off
set a=www.jb51.net
set var=%a:~1,2%
echo %var%
pause
2、%Var:~-len%
截取倒数len位
3、%Var:~0,-len%
截取从第一位开始,倒数第len位结束的值。
例子
复制代码代码如下:
@echo off
set a=www.jb51.net
set var=%a:~0,-3%
echo %var%
pause
执行后,我们发现显示的是"www.jb51.net",少了"et"
从结果分析,很容易分析出,这是把变量a的值从0位开始,
到倒数第三位之间的值全部赋予给var
您可能感兴趣的文章:
文章浏览阅读948次,点赞24次,收藏26次。近日,SAP官方发布最新BWH Benchmark基准测试结果,浪潮信息NF8480G7四路HANA一体机以每小时执行17044次查询的成绩,刷新该测试最高纪录,为全球金融、高端制造、零售、能源等行业用户的商业智能分析,提供高效、领先的算力平台,从容应对快速多变的商业环境。
文章浏览阅读1.1w次,点赞5次,收藏22次。开发板购买链接https://item.taobao.com/item.htm?spm=a2oq0.12575281.0.0.50111deb2Ij1As&ft=t&id=626366733674开发板简介开发环境搭建 windows源码示例: 0_Hello Bug (ESP_LOGX与printf) 工程模板/打印调试输出 1_LED LED亮灭控制 ..._基于vscode的esp32开发,读取dht11传感器数据到led显示屏上
文章浏览阅读623次。简单题,但是不会_a game about increasing sequences
文章浏览阅读2.3k次。OE非:输出使能,本实验接地使用。记得接地!单片机手动接地!J24模块!RCLK:储存寄存器时钟输入SRCLR非:复位,本单片机默认接VCC,不用管。SRCLK:移位寄存器时钟输入SER:串行输入QA-QH:8位并行输出QH非:串行输出 本实验595的工作:SRCLK每接到一个上升沿,就把SER的值储存起来;当存够8位后,给RCLK一个上升沿,储存起来的数就被放到QA-QH,第一个存进来的数放到QH(高位的数放高位)。(自己的理解,不知对错)列由P0控..._stc8g 驱动74hc595
文章浏览阅读492次。文件树如下:首先是utils包:functions.py配置代码如下:from flask_sqlalchemy import SQLAlchemyfrom flask_debugtoolbar import DebugToolbarExtensionfrom flask_restful import Apifrom flask_marshmallow import Marshmallowdb = SQLAlchemy()debugtoolbar = DebugToolb_get_db_uri
文章浏览阅读2.1k次。见字如面,我是军哥!我很少推荐别人的公众号,因为我能看上的原创公众号并不多,让我主动推荐就更难了。今天这位朋友叫宇宙,认识有两年了,在支付行业里非常有名气,最近闲着无聊翻了他多篇原创文章之后,我发现他对支付这种极其复杂领域的业务架构/产品架构已经到了炉火纯青的地步了,推荐给各位,我相信你一定会回头来感谢我的!下面是他的一篇原创,本文头部和尾部都有他的公号卡片,文章不长,请认真看完~从一次美团外卖的..._美团外卖单子小票有什么信息
文章浏览阅读655次。运算符分为:1.算术运算符2.条件运算符3.逻辑运算符4.位运算符5.三元运算符在Lua中不支持位运算符和三位运算符,但是可以间接实现三元运算符1.算术运算符(+、-、*、/、%、^(幂运算符))注意:Lua中没有++,–,+=,-=,*=,/=,%=2.条件运算符(and ,or,not) 注意:Lua中的条件运算符就这三个,没有&&,||,!=3.逻辑运算符(> ,<, =, >=, <=, ==,~=) 注意:Lua中的不等于是"~="pri_lua &&
文章浏览阅读1.7k次。点击上方“3D视觉工坊”,选择“星标”干货第一时间送达作者:梦寐mayshinehttps://zhuanlan.zhihu.com/p/129681081本文转载自知乎,作者已授权,未..._图像 3d模型 csdn
文章浏览阅读1.2w次,点赞9次,收藏54次。首先:A题是连续型问题,是“数值分析”领域的内容,需要熟练掌握偏微分方程以及精通将连续性方程离散化求解的编程能力。这时,队伍里最好是有一个纯数学基础好的(偏微分方程、复变函数、信号与系统等等),还需要有两个擅长连续型问题编程的同学,两个人都比较擅长编程这一点很重要,既可以防止一个人编程的话,思路可能有所偏颇,又可以使得两个人在相互碰撞中产生新的灵感。B题的话可能是离散型问题,对于B题在编程上,一定需要比较熟悉计算机的“算法与数据结构”这类离散型编程问题的同学。C题属于大数据类问题,几乎都是关于数_2021年美赛b题思路
文章浏览阅读780次。LAN IP地址网站划分详解IP和子网掩码我们都知道,IP是由四段数字组成,在此,我们先来了解一下3类常用的IPA类IP段 0.0.0.0 到127.255.255.255B类IP段 128.0.0.0到191.255.255.255C类IP段 192.0.0.0到223.255.255.255 XP默认分配的子网掩码每段只有255或0 A类的默认子网_网址划分
文章浏览阅读637次,点赞29次,收藏14次。javascript是前端必要掌握的真正算得上是编程语言的语言,学会灵活运用javascript,将对以后学习工作有非常大的帮助。掌握它最重要的首先是学习好基础知识,而后通过不断的实战来提升我们的编程技巧和逻辑思维。这一块学习是持续的,直到我们真正掌握它并且能够灵活运用它。如果最开始学习一两遍之后,发现暂时没有提升的空间,我们可以暂时放一放。继续下面的学习,javascript贯穿我们前端工作中,在之后的学习实现里也会遇到和锻炼到。真正学习起来并不难理解,关键是灵活运用。
文章浏览阅读2.6k次,点赞4次,收藏31次。版权声明:本文为本文为博主原创文章,转载请注明出处。如有错误,欢迎指正。文章目录xenomai 内核系统调用一、32位Linux系统调用二、32位实时系统调用三、 64位系统调用五、 实时系统调用表cobalt_syscalls六、实时系统调用权限控制cobalt_sysmodes参考xenomai 内核系统调用解析系统调用是了解内核架构最有力的一把钥匙,在这之前先搞懂xenomai与linux两个内核共存后系统调用是如何实现的。为什么需要系统调用linux内核中设置了一组用于实现系统功能的子程_xenomai